root/trunk/IssBuilderServiceClass.pas

///////////////////////////////////////////////////////////
//                     GGBuildTools                      //
//    Набор утилит для сборки проектов Gipat Group       //
//             Copyright (C) 2007 Gipat Group            //
//              Распространяется на условиях             //
//    Gipat Group's opened EI-editor-utility license     //
//                      версии 1.0                       //
//                                                       //
//                  www.gipatgroup.org                   //
///////////////////////////////////////////////////////////

//К работе над данным файлом приложили руки, ноги.... короче аффтары:
// 1) Sagrer (sagrer@yandex.ru)

////////////////////////////////////////////////////////////////////////

////////////////////////////////////////////////////////////
//             Служебный класс для IssBuilder             //
////////////////////////////////////////////////////////////

unit IssBuilderServiceClass; 

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils, Forms, ExtraFunctionsLcl, GGConsUtilServiceClass, GGBuildToolsShared, ExtraFileUtilsLCL,
  IssBuilderLogic, TranslManager;
  
const
  GGBT_IssBuilderAppName = ' - Inno Setup builder';
  
type
  TIssBuilderServiceClass = class (TGGConsUtilServiceClass)       //Класс с основным функционалом и данными IssBuilder
  private
  protected
    LogicClass : TIssBuilderLogic;

    //Защищенные методы.
    procedure PostExternalMessage(const TextMessage : AnsiString);    //Функция для вывода мессаги другими объектами.
  public
    //Переменные
    SconfFilename : AnsiString;

    //Конструкторы-деструкторы...
    constructor Create; override;
    destructor Destroy; override;

    //Открытые методы...
    procedure ProcessParameters;  override;     //Проверить параметры командной строки.
    procedure DoWork;        override;          //Выполнить боевую задачу %).
    procedure ShowDescription; override;        //Вывести описание утилиты.
    procedure ShowOptions;  override;           //Вывести справку по использованию тулсы.
    procedure ProcessExtraSconfParams;          //Прочитать параметры, перекрывающие настройки sconf.
  end;

var
  IssBuilderServClass : TIssBuilderServiceClass;

implementation

/////////////////////////////////////////////
//         TIssBuilderServiceClass         //
/////////////////////////////////////////////

//-----------------------------------------//
//        Конструкторы-деструкторы...      //
//-----------------------------------------//

constructor TIssBuilderServiceClass.Create;
begin
  //Проставить дефолтные значения...
  SconfFilename := '';

  //Создать вложенные объекты классов...
  LogicClass := TIssBuilderLogic.Create;

  //Вбить имя приложения.
  Self.GGConsAppName := GGBT_IssBuilderAppName;

  //Выполнить конструктор предка...
  inherited;
end;

destructor TIssBuilderServiceClass.Destroy;
begin
  //Выкидываем мусор
  LogicClass.Free;

  //Выполнить унаследованный деструктор
  inherited;
end;

//------------------------------------------//
//           Защищенные методы...           //
//------------------------------------------//

procedure TIssBuilderServiceClass.PostExternalMessage(const TextMessage : AnsiString);
//Функция для вывода мессаги другими объектами.
begin
  Writeln(TextMessage);
end;

//------------------------------------------//
//            Открытые методы...            //
//------------------------------------------//

procedure TIssBuilderServiceClass.ProcessParameters;
//Проверить параметры командной строки.
begin
  //Выполнить унаследованную функцию
  inherited;

  if Application.HasOption('filepath') then begin
    //Прочитать имя файла проекта.
    Self.SconfFilename := Application.GetOptionValue('filepath');
  end;
  
  if Application.HasOption('nocachewrite') or Application.HasOption('n') then begin
    //Запрещаем записывать что-либо в кеш.
    Self.LogicClass.NoCacheWrite := true;
  end;
  
  //Параметры, переопределяющие настройки из sconf обрабатываются отдельно. См код в DoWork().
end;

procedure TIssBuilderServiceClass.DoWork;
//Выполнить боевую задачу %).
var
  AllOk : Boolean;
begin
  //Выполнить нужно одну из задач - по её завершении ProcessFurther := false
  //и дальше нифига не выполняется.

  //Выполнить унаследованную функцию
  inherited;
  
  //Дополнительная инициализация.
  AllOk := true;

  //Если ничего до сих пор не выполнилось - то выполняем боевую задачу....
  if ProcessFurther = true then begin
    //Блокировка других веток
    ProcessFurther := false;
    //Работаем....
    if Application.HasOption('filepath') = true then begin
      //Собсно выполняем боевую задачу.
      //Выводим версию софтины...
      Self.ShowVersion();
      Writeln('');
      //Превращаем локальный путь в глобальный.
      Self.SconfFilename := ResolveLocalPath(Self.SconfFilename,GetCurrentDir);

      //В данный момент у нас должен быть глобальный путь. Проверим существует ли файл.
      if FileExists(Self.SconfFilename) = true then begin
        //Существует.
        
        //Читаем Sconf.
        Writeln(_('Reading sconf from ')+Self.SconfFilename);
        AllOk := Self.LogicClass.ProjectSconf.Load(Self.SconfFilename);
        Self.LogicClass.SconfFilePath := Self.SconfFilename;
        
        if AllOk = true then begin
          //Прочитали.
          Writeln(_('Readed.'));
          
          //Теперь надо перекрыть настройки в sconf перекрывающими параметрами из командной строки, если они там такие есть.
          Self.ProcessExtraSconfParams;
          
          //Ок. Ну, а теперь, собсно гря, настраиваем и запускаем в работу логику.
          Self.LogicClass.PostExternalMessage := @Self.PostExternalMessage;
          AllOk := Self.LogicClass.ProcessSconf();
          
          //Если фсеок - то выводим сообщение что типо увсе зделано.
          if AllOk = true then begin
            //Фсеок.
            Writeln(_('Done.'));
            Writeln('');
          end
          else begin
            //Был какой-то обломс.
            Writeln(_('Error. IssBuilding stopped.'));
            Writeln('');
          end;
        end;
        
      end
      else begin
        //Облом. Сообщаем про ошибк.
        Writeln(_('Error! Project sconf file is not exists! : '));
        Writeln(Self.SconfFilename);
        Writeln('');
      end;
    end
    else begin
      //Обломс. Нехватает опции которая обязательна для работы софтины.
      Self.ShowHelp();
      Writeln(_('Error!!! "--filepath=<value>" option is required!'));
      Writeln('');
    end;
  end;

end;

procedure TIssBuilderServiceClass.ShowDescription;
//Вывести описание утилиты.
begin
  inherited;
  Writeln(_('Description:'));
  Writeln(_('             Generates *.iss Inno Setup scripts for your program''s installs,'));
  Writeln(_('             then launching Inno Setup compiler to create an installation'));
  Writeln(_('             package.'));
end;

procedure TIssBuilderServiceClass.ShowOptions;
//Вывести справку по использованию тулсы.
begin
  //Вызвать унаследованную функцию...
  inherited;

  //И собсно запостить нашенские дополнения %).
  Writeln(_('          --filepath=<value> : sets path to the project''s configuration file.'));
  Writeln(_('          -n, --nocachewrite : don''t save anything into cache, ignoring'));
  Writeln(_('            project''s configuration file options.'));
  Writeln('          ');
  Writeln(_('Options to redeclare [IssBuilder] section''s elements from project''s'));
  Writeln(_('configuration file:'));
  Writeln('          ');
  Writeln(_('          --FilesDir=<value> : path (relative to project''s root or absolute)'));
  Writeln(_('            to directory with files for installation. All paths may be relative'));
  Writeln(_('            to project''s root or they may be absolute.'));
  Writeln(_('          --DefaultIssName=<value> : name of default *.iss file.'));
  Writeln(_('          --OutputDir=<value> : directory, where to put compiled installs.'));
  Writeln(_('          --VersionsCacheDir=<value> : directory for versions cache.'));
  Writeln(_('          --SaveToCache=<value> : value is 0 or 1. If 1 - saves all version''s'));
  Writeln(_('            files into cache (from FilesDir), not only *.iss and *.flist files.'));
  Writeln(_('          --CreateFull=<value> : value is 0 or 1. If 1 - creates a full'));
  Writeln(_('            installation package (full version and may be updates).'));
  Writeln(_('          --CreateFull_AllowUpdate=<value> : value is 0 or 1. If 1 - gives full'));
  Writeln(_('            installation an ability to update previous versions without they '));
  Writeln(_('            uninstallation.'));
  Writeln(_('          --CreateFull_UpdVers=<value> : What previous versions to make'));
  Writeln(_('            updatable - if value is "All" - all previous versions which are'));
  Writeln(_('            exists in a cache will be updatable. If value is "From:X", where X'));
  Writeln(_('            is a ver number (4 nubers, delimited by dots) - all versions from'));
  Writeln(_('            X (including it), which are exists in a cache will be updatable. If'));
  Writeln(_('            value is a number - last value number of versions, which are exists'));
  Writeln(_('            in a cache will be updatable.'));
  Writeln(_('          --CreateSeparateUpds=<value> : value is 0 or 1. If 1 - separate'));
  Writeln(_('            update installs, which can only update a speciefic one version'));
  Writeln(_('            will be created.'));
  Writeln(_('          --CreateSeparateUpds_UpdVers=<value> : same as CreateFull_UpdVers.'));
  Writeln(_('          --CreateCumulateUpdate=<value> : value is 0 or 1. If 1 - cumulative'));
  Writeln(_('            update install, which can update a number of different versions'));
  Writeln(_('            will be compilled.'));
  Writeln(_('          --CreateCumulateUpdate_UpdVers=<value> : same as CreateFull_UpdVers.'));
end;

procedure TIssBuilderServiceClass.ProcessExtraSconfParams;
//Прочитать параметры, перекрывающие настройки sconf.
begin

  if Application.HasOption('FilesDir') then begin
    Self.LogicClass.ProjectSconf.IssBuilderSection.FilesDir := Application.GetOptionValue('FilesDir');
  end;
  
  if Application.HasOption('DefaultIssName') then begin
    Self.LogicClass.ProjectSconf.IssBuilderSection.DefaultIssName := Application.GetOptionValue('DefaultIssName');
  end;
  
  if Application.HasOption('OutputDir') then begin
    Self.LogicClass.ProjectSconf.IssBuilderSection.OutputDir := Application.GetOptionValue('OutputDir');
  end;
  
  if Application.HasOption('VersionsCacheDir') then begin
    Self.LogicClass.ProjectSconf.IssBuilderSection.VersionsCacheDir := Application.GetOptionValue('VersionsCacheDir');
  end;
  
  if Application.HasOption('SaveToCache') then begin
    Self.LogicClass.ProjectSconf.IssBuilderSection.SaveToCache := StrToBool(Application.GetOptionValue('SaveToCache'));
  end;
  
  if Application.HasOption('CreateFull') then begin
    Self.LogicClass.ProjectSconf.IssBuilderSection.CreateFull := StrToBool(Application.GetOptionValue('CreateFull'));
  end;
  
  if Application.HasOption('CreateFull_AllowUpdate') then begin
    Self.LogicClass.ProjectSconf.IssBuilderSection.CreateFull_AllowUpdate := StrToBool(Application.GetOptionValue('CreateFull_AllowUpdate'));
  end;
  
  if Application.HasOption('CreateFull_UpdVers') then begin
    Self.LogicClass.ProjectSconf.IssBuilderSection.CreateFull_UpdVers := Application.GetOptionValue('CreateFull_UpdVers');
  end;
  
  if Application.HasOption('CreateSeparateUpds') then begin
    Self.LogicClass.ProjectSconf.IssBuilderSection.CreateSeparateUpds := StrToBool(Application.GetOptionValue('CreateSeparateUpds'));
  end;
  
  if Application.HasOption('CreateSeparateUpds_UpdVers') then begin
    Self.LogicClass.ProjectSconf.IssBuilderSection.CreateSeparateUpds_UpdVers := Application.GetOptionValue('CreateSeparateUpds_UpdVers');
  end;
  
  if Application.HasOption('CreateCumulateUpdate') then begin
    Self.LogicClass.ProjectSconf.IssBuilderSection.CreateCumulateUpdate := StrToBool(Application.GetOptionValue('CreateCumulateUpdate'));
  end;
  
  if Application.HasOption('CreateCumulateUpdate_UpdVers') then begin
    Self.LogicClass.ProjectSconf.IssBuilderSection.CreateCumulateUpdate_UpdVers := Application.GetOptionValue('CreateCumulateUpdate_UpdVers');
  end;

end;

/////////////////////////////////
initialization

//Инициализация %). Выделим память, создадим всякую херню... как обычно в общем %)
begin
  IssBuilderServClass := TIssBuilderServiceClass.Create;
  //Включим перевод с языка по умолчанию.
  TranslMan.SetMODir(ResolveLocalPath('..\Languages',ExtractFilePath(Application.ExeName)));
  TranslMan.EnableLanguageDefault;
end;

finalization
//Мочим все лишнее...
begin
  IssBuilderServClass.Free;
end;

end.