root/trunk/LCLTextFileInString.pas

////////////////////////////////////////////////////////////
//              Класс работы с файлом, как                //
//                с паскалевской строкой                  //
//               + функции для текстовика                 //
//                     LCL-вариант                        //
//                       v 1.3                            //
//                                                        //
//              Copyright (C) 2007 Sagrer                 //
//          Распространяется на условиях LGPL 2.1         //
//                  см. файл lgpl.txt                     //
//                                                        //
//                  sagrer@yandex.ru                      //
////////////////////////////////////////////////////////////

//К работе над данным файлом приложили руки, ноги.... короче аффтары:
// 1) Sagrer (sagrer@yandex.ru)

////////////////////////////////////////////////////////////////////////

unit LCLTextFileInString;
////////////////////////////////////////////////////////
//        Как бы надстройка над TFileInString         //
//       Набор фунок для работы с файло-строкой       //
//         подразумевая, что это текстовый файл       //
//                 Crafted by Sagrer                  //
////////////////////////////////////////////////////////

{$mode objfpc}{$H+}

interface
uses LCLFileInString;

type
  TTextFileInString = class (TFileInString)
  public
    //Класс для работы с текстовиком на основе TFileInString
    Cursor : LongInt;
    //Конструкторы-деструкторы
    constructor Create; override;                           //Конутруктор  %).
    Destructor Destroy; override;                           //Типа деструктор.
    //Методы
    Function Load(const FName : AnsiString) : boolean; override; //Загрузить из файла.
    Procedure MakNewFile(); override;                              //"Создать новый файл" %).
    Procedure AddStr(const Str : AnsiString);
    Function ReadStrLn(const FirstByte : LongInt) : AnsiString;
    Function CurReadStr : AnsiString;
    Function CurReadLn : AnsiString;
    Function Eof : boolean;
    Function CurRead(const BytesRead : LongInt) : AnsiString;
    Procedure InsertString(const Pos : LongInt; Str : AnsiString);
    Procedure ReplaceString(const Pos : LongInt; Str : AnsiString);
  end;

implementation

////////////////////////////////////////
//        TTextFileInString           //
////////////////////////////////////////

//------------------------------------//
//      Конструкторы-деструкторы      //
//------------------------------------//

Constructor TTextFileInString.Create;
//Конутруктор  %).
begin
  inherited;       //Вызов родительского метода...
  //Ставим курсор на единицу...
  Cursor := 1;
end;

Destructor TTextFileInString.Destroy;
begin
  //Типа деструктор.
  inherited;
end;

//------------------------------------//
//             Методы                 //
//------------------------------------//

Function TTextFileInString.Load(const FName : AnsiString) : boolean;
//Загрузить из файла.
begin
  Result := inherited;
  Self.Cursor := 1;
end;

Procedure TTextFileInString.MakNewFile();
//"Создать новый файл" %).
begin
  inherited;
  Self.Cursor := 1;
end;

Procedure TTextFileInString.AddStr(const Str : AnsiString);
begin
  FileString := FileString+Str+#13#10;
end;

Function TTextFileInString.ReadStrLn(const FirstByte : LongInt) : AnsiString;
var
  I, TempInt : LongInt;
begin
  //Прочитать строку начиная с нужного байта.
  //Курсор не трогать.

  //В начале - найти конец строки.
  I := FirstByte;
  TempInt := Length(FileString);
  repeat
    If (FileString[I] <> #13) and (FileString[I] <> #10) and (FileString[I] <> #12) and (I <> TempInt+1) then begin
      I := I+1;
    end;
  until (FileString[I] = #13) or (FileString[I] = #10) or (FileString[I] = #12) or (I = TempInt+1);

  //скопировать нужное число байтов (оно вычисляется также ниже).
  result := ReadStr(FirstByte,I-FirstByte);
end;

Function TTextFileInString.CurReadStr : AnsiString;
begin
  //Функа читает строку с точки курсора, и передвигает курсор в конец строки.
  Result := ReadStrLn(Cursor);
  Cursor := Cursor+Length(Result);
end;

Function TTextFileInString.CurReadLn : AnsiString;
begin
  //Функа читает строку с точки курсора, и передвигает курсор на начало след. строки,
  //если она вообще существует.
  Result := CurReadStr;
  If (Cursor <> Length(FileString)+1) and ((Length(FileString)+1)  - (Cursor) >=2) and (FileString[Cursor] = #13) then begin
    //Если курсор еще не в конце, стоит на #13, и есть еще 2 байта, то...
    Cursor := Cursor+2;
  end
  else if (Cursor <> Length(FileString)+1) and ((Length(FileString)+1)  - (Cursor) >=1) and (FileString[Cursor] <> #13) then begin
    //Если курсор еще не в конце, стоит не на #13 и есть еще 1 байта, то...
    Cursor := Cursor+1;
  end;
end;

Function TTextFileInString.Eof : boolean;
begin
  //Если курсор лежит в конце файла, то типа тру...

  result := false;  //по умолчанию...

  If Cursor = Length(FileString)+1 then begin
    result := true;
  end
  else begin
    If Cursor > Length(FileString)+1 then begin
      //Если курсор за пределами файла вдруг оказался,
      //то поправить, и вернуть тру...
      Cursor := Length(FileString)+1;
      result := true;
    end;
  end;
end;

Function TTextFileInString.CurRead(const BytesRead : LongInt) : AnsiString;
begin
  //Функа, чтоб прочитать нужное число байтов из строки файла,
  //передвинув при этом курсор.

  result := ReadStr(Cursor,BytesRead);
  Cursor := Cursor+BytesRead;
end;

Procedure TTextFileInString.InsertString(const Pos : LongInt; Str : AnsiString);
var
  TempStr : AnsiString;
begin
  //Функа, чтоб вставить (хоть в середину файла - в общем
  // - на нужную позицию) строку.

  TempStr := ReadStr(1,Pos-1); //Считать кусок строки до указанной позиции.
  TempStr := TempStr+Str;  //Вставить строку...
  If Pos-1 <> Length(FileString) then begin
    //Если есть еще остаток строки...
    TempStr := TempStr+ReadStr(Pos,Length(FileString)-Pos+1);  //Считать остаток строки.
  end;  
  FileString := TempStr;
end;

Procedure TTextFileInString.ReplaceString(const Pos : LongInt; Str : AnsiString);
var
  TempStr, buf : AnsiString;
  TempPos : LongInt;
begin
  //Функа чтоб заменить (в середине файла гденить например)
  //строку на строку (тоесть до #13#10 или до конца строки собсно...)
  TempStr := ReadStr(1,Pos-1); //Считать кусок строки до указанной позиции.
  TempStr := TempStr+Str;  //Вставить строку...
  If Pos-1 <> Length(FileString) then begin
    //Если есть еще остаток строки...
    buf := ReadStrLn(Pos);    //Типа получить строку, и по ней узнать
    //сколько в строке, попадающей под замену символов.
    TempPos := Pos+Length(buf);

    TempStr := TempStr+ReadStr(TempPos,Length(FileString)-TempPos+1);  //Считать остаток строки.
  end;
  FileString := TempStr;
end;

end.