root/trunk/MOExtractor.pas

///////////////////////////////////////////////////////////
//                    MOExtractor                        //
//     Модуль с классом-расширением класса MOFile        //
//                   из модуля gettext.                  //
//      Содержит дополнительный функционал для более     //
//         простого подключения mo-файлов, а также       //
//       для автоматического перекодирования строк в     //
//           используемую программой кодировку.          //
//                                                       //
//                Copyright (C) 2008 Sagrer              //
//              Распространяется на условиях             //
//                      LGPL v2.1                        //
//                                                       //
//                  версия модуля 0.1                    //
//                                                       //
//                   sagrer@yandex.ru                    //
///////////////////////////////////////////////////////////

//К работе над данным файлом приложили руки, ноги.... короче аффтары:
// 1) Sagrer (sagrer@yandex.ru)

////////////////////////////////////////////////////////////////////////

unit MOExtractor;

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils, gettext, ExtraFileUtilsLCL, LConvEncoding;
  
type
  TMOExtractor = class(TMOFile)    //Класс для выковыривания строк из mo.
  private
  protected
    //Защищенные переменные
    CurrLang : String;                   //Текущий язык
    CurrFallbackLang : String;           //Текущий язык в минимальной форме
    CurrEncoding : String;               //Текущая кодировка
    MODir : String;                      //Директория с *.mo-файлами.
    MOPref : String;                     //Префикс к имени *.mo-файла.
    IsDummy : Boolean;                   //Является ли объект заглушкой без функции перевода и подключенного *.mo.
  public
    //Открытые переменные.
    LangConnected : Boolean;             //Подключен ли *.mo для языка.
    
    //Конструкторы-деструкторы
    constructor Create(const MODirectory, MOPrefix : String; const DefLang : String = 'default');  virtual;    //Конструктор, автоматически подключающий файл {MODirectory}\{MOPrefix}{lang}.mo, предварительно определяет {lang}.
    constructor CreateAsDummy;  virtual;  //Конструктор, создающий объект-заглушку, тупо пропускающий строки сквозь себя, без перевода.

    //Открытые методы.
    function _(AOrig: String) : String; virtual;      //Выдернуть перевод строки, автоматически перекодированный в текущую кодировку.
    function GetCurrLang : String;    //Вернуть текущий используемый язык.
  end;
  
//Глобальные функции
function GetUIEncoding: string;    //Gets encoding for a user interface - it may not be the same as a system encoding.

implementation

/////////////////////////////////////////////
//          TConsUtilServiceClass          //
/////////////////////////////////////////////

//-----------------------------------------//
//        Конструкторы-деструкторы...      //
//-----------------------------------------//

constructor TMOExtractor.Create(const MODirectory, MOPrefix : String; const DefLang : String = 'default');
//Конструктор, автоматически подключающий файл {MODirectory}\{MOPrefix}{lang}.mo, предварительно определяет {lang}.
var
  tstr : String;
begin
  //Запомним переданные параметры...
  Self.MODir := MODirectory;
  Self.MOPref := MOPrefix;
  //Определим текущий язык...
  GetLanguageIDs(CurrLang, CurrFallbackLang);
  if DefLang <> 'default' then begin
    //Если язык указан в параметрах - то использовать его.
    CurrFallbackLang := DefLang;
  end;
  //Определим кодировку...
  CurrEncoding := GetUIEncoding();
  //Отмечаемся что объект - не заглушка
  Self.IsDummy := false;
  //Проверяем - существует ли файлик для языка?
  tstr := AddLastSlash(MODirectory)+MOPrefix+CurrFallbackLang+'.mo';
  if FileExists(AddLastSlash(MODirectory)+MOPrefix+CurrFallbackLang+'.mo') = true then begin
    //Файлик найден.
    //Теперь можно этот файлик подключить унаследованным конструктором.
    Self.LangConnected := true;
    try
      inherited Create(AddLastSlash(MODirectory)+MOPrefix+CurrFallbackLang+'.mo');
    except
      //Ошибка чтения файла - придется работать как будто файла не было.
      Self.LangConnected := false;
    end;
  end
  else begin
    //Файл не найден - при переводе работаем по принципу "что спросили то и вернем"
    Self.LangConnected := false;
  end;
end;

constructor TMOExtractor.CreateAsDummy();
//Конструктор, создающий объект-заглушку, тупо пропускающий строки сквозь себя, без перевода.
begin
  //Все-же определим текущий язык и кодировку, вдруг потребуется...
  GetLanguageIDs(CurrLang, CurrFallbackLang);
  CurrEncoding := GetDefaultTextEncoding();
  //Отмечаем, что у нас тупая заглушка...
  Self.LangConnected := false;
  Self.IsDummy := true;
end;

//-----------------------------------------//
//             Открытые методы.            //
//-----------------------------------------//

function TMOExtractor._(AOrig: String) : String;
//Выдернуть перевод строки, автоматически перекодированный в текущую кодировку.
begin
  if (Self.LangConnected = true) and (Self.IsDummy = false) then begin
    //Извлекаем искомую строку...
    Result := ConvertEncoding(Self.Translate(AOrig),'utf-8',Self.CurrEncoding);
    //Если в mo не найдено такой строки - вернуть оригинал.
    if (Result = '') and (AOrig <> '') then Result := AOrig;
  end
  else begin
    //Файлик не был прочитан - возвращаем то что спросили, без перевода.
    Result := AOrig;
  end;
end;

function TMOExtractor.GetCurrLang() : String;
//Вернуть текущий используемый язык.
begin
  Result := Self.CurrFallbackLang;
end;

/////////////////////////////////////////////
//            Глобальные функции           //
/////////////////////////////////////////////

function GetUIEncoding: string;
//Gets encoding for a user interface - it may not be the same as a system encoding.
begin
  Result := GetDefaultTextEncoding;
  {$IFDEF Windows}
  if System.IsConsole = true then begin
    if Result = 'cp1251' then begin
      //Russian versions of Windows 9x-XP use a cp866 encoding for console i\o.
      Result := 'cp866';
    end;
  end;
  {$ENDIF}
end;

end.