root/trunk/PascalCodeModifier.pas

////////////////////////////////////////////////////////////
//            Класс для работы с файлом с кодом           //
//             на паскале - чтение и изменение            //
//                    элементов кода                      //
//                        v 0.1                           //
//                                                        //
//              Copyright (C) 2007 Sagrer                 //
//          Распространяется на условиях LGPL 2.1         //
//                  см. файл lgpl.txt                     //
//                                                        //
//                   sagrer@yandex.ru                     //
////////////////////////////////////////////////////////////

//К работе над данным файлом приложили руки, ноги.... короче аффтары:
// 1) Sagrer (sagrer@yandex.ru)

////////////////////////////////////////////////////////////////////////

unit PascalCodeModifier;

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils, LCLTextFileInString, CodeToolManager,
  CodeTree, CodeCache, CodeAtom, TranslManager;
  
type
  RPascalConst = record      //Структура с инфой о константе.
    ConstStart : LongInt;
    ConstEnd : LongInt;
    Name : AnsiString;
    NameStart : LongInt;
    NameEnd : LongInt;
    Value : AnsiString;
    ValueStart : LongInt;
    ValueEnd : LongInt;
  end;

  APascalConsts = array of RPascalConst;    //Массив констант.

  RPascalFunction = record       //Структура с инфой о функции.
    FunctionStart : LongInt;
    FunctionEnd : LongInt;
    Name : AnsiString;
    NameStart : LongInt;
    NameEnd : LongInt;
    IsProcedure : Boolean;
    IsDeclaration : Boolean;
  end;

  APascalFunctions = array of RPascalFunction;    //Массив с функциями.

  TPascalCodeModifier = class (TTextFileInString)
  private
    //Буффер и експлорер для кода.
    CodeBuf : TCodeBuffer;                //Буффер.
    ACodeTool : TCodeTool;                //Експлорер.
    CodeToolsAreUnderControl : Boolean;    //Управляет ли уже ими какой-либо метод?
  public
    //Переменные.
    //Переменные с инфой о блоках.
    Consts : APascalConsts;              //Константы...
    Functions : APascalFunctions;    //Функции...
    //Служебные.
    ErrorMessage : AnsiString;   //Для инфы про последнюю ошибку...
    ErrorPosition : LongInt;     //Для инфы про номер символа последней ошибки.
    ErrorLine : LongInt;         //Для инфы про номер строки последней ошибки.

    //Конструкторы-деструкторы
    constructor Create; override;                           //Конутруктор  %).
    Destructor Destroy; override;                           //Типа деструктор.
    //Открытые методы.
    Function Load(const FName : AnsiString) : boolean; override; //Загрузить из файла.
    Procedure MakNewFile; override;                              //"Создать новый файл" %).
    Procedure GetErrorLineFromPos();                             //Получить номер строки по позиции ошибки в файле.
    //--Блоки, чтение для них инфы--
    procedure ResetConstsBlock();                                    //Обнулить инфу о блоке констант.
    procedure ResetFunctionsBlock();                                 //Обнулить инфу о блоке функций.
    procedure ResetBlocksInfo();                                     //Обнулить инфу о блоках кода.
    procedure ResetConst(var ConstToReset : RPascalConst);           //Обнулить инфу о константе.
    procedure ResetFunction(var FuncToReset : RPascalFunction);      //Обнулить инфу о функции.
    function ParseConsts() : Boolean;                                //Пропарсить блок констант...
    function ParseFunctions() : Boolean;                             //Пропарсить блок функций...
    function ReParseFile() : Boolean;                                //Пропарсить текущий файл...
    function GetPosForFirstFunction() : Integer;                     //Получить позицию в которую можно вписывать самую первую функцию.
    //--Чтение и модификация элементов кода--
    function ReadCodeConstValue(const ConstName : AnsiString) : AnsiString;   //Прочитать значение конкретной константы.
    function WriteCodeConstValue(const ConstName, ConstValue : AnsiString) : Boolean;    //Записать значение конкретной константы.
    function ReadFunctionName(const FullFunctionText : AnsiString) : AnsiString;   //Выпарсить имя функции из полного её кода.
    function FunctionIsExists(const FunctionName : AnsiString) : Boolean;    //Существует ли функция?
    function FunctionIsExistsByText(const FullFunctionText : AnsiString) : Boolean;    //Существует ли функция? Поиск идет по имени, которое берется из полного кода функции.
    function GetFunctionIndex(const FunctionName : AnsiString) : Integer;    //Получить номер функции с таким именем в массиве с инфой.
    function GetFullFunctionText(const FunctionIndex : Integer) : AnsiString;   //Получить полный код функции по её номеру в массиве.
    function GetFullFunctionText(const FunctionName : AnsiString) : AnsiString;   //Получить полный код функции по её имени.
    function WriteFunction(const FunctionIndex : Integer; const FullFunctionText : AnsiString) : Boolean;   //Записать функцию в код, если она уже есть - заменить.
    function WriteFunction(const FunctionName, FullFunctionText : AnsiString) : Boolean;   //Записать функцию в код, если она уже есть - заменить.
  end;

implementation

//////////////////////////////////////////////
//          TPascalCodeModifier             //
//////////////////////////////////////////////

//------------------------------------//
//      Конструкторы-деструкторы      //
//------------------------------------//

Constructor TPascalCodeModifier.Create;
//Конутруктор  %).
begin
  inherited;       //Вызов родительского метода...

  //Инициализовать пустые вложенные массивы в структурах.
  SetLength(Self.Consts, 0);
  SetLength(Self.Functions, 0);

  //И прочиатим инфу объекта.
  Self.MakNewFile;
end;

Destructor TPascalCodeModifier.Destroy;
//Типа деструктор.
begin
  inherited;
  Self.ResetBlocksInfo();
end;

//------------------------------------------//
//           Закрытые методы...             //
//------------------------------------------//

//------------------------------------------//
//            Открытые методы...            //
//------------------------------------------//

Function TPascalCodeModifier.Load(const FName : AnsiString) : boolean;
//Загрузить из файла.
begin
  Self.MakNewFile;
  Result := inherited;
end;

Procedure TPascalCodeModifier.MakNewFile;
//"Создать новый файл" %).
begin
  inherited;
  //Чистим инфу про ошибки.
  Self.ErrorMessage := 'none';
  Self.ErrorPosition := 0;
  Self.ErrorLine := 0;
  //Забиваем инфу в переменные.
  Self.ACodeTool := nil;
  Self.CodeBuf := nil;
  Self.CodeToolsAreUnderControl := false;
  //Чистим блоки с инфой про код.
  Self.ResetBlocksInfo();
end;

Procedure TPascalCodeModifier.GetErrorLineFromPos();
//Получить номер строки по позиции ошибки в файле.
var
  TempCursor, CurrLine : LongInt;
begin
  if Self.ErrorPosition <= Self.Siz then begin
    //Точка ошибки в пределах файла.
    CurrLine := 1;
    TempCursor := 0;
    Self.ErrorLine := 0;
    repeat
      //Собсно бежим по строкам и определяем на какой строке курсор будет в точке ошибки.
      TempCursor := TempCursor+1;
      if Self.FileString[TempCursor] = #10 then begin
        //Конец строки.
        CurrLine := CurrLine+1;
      end;
      if Self.ErrorPosition = TempCursor then begin
        //Нашли строку с ошибкой.
        Self.ErrorLine := CurrLine;
      end;
    until (TempCursor = Self.Siz) or (Self.ErrorLine <> 0);
  end
  else begin
    //Точка ошибки за пределами файла.
    Self.ErrorLine := 0;
  end;
end;

//---------------------------------------------//
//      --Блоки, чтение для них инфы--         //
//---------------------------------------------//

procedure TPascalCodeModifier.ResetConstsBlock();
//Обнулить инфу о константах.
begin
  if Length(Self.Consts) > 0 then begin
    SetLength(Self.Consts, 0);
  end;
end;

procedure TPascalCodeModifier.ResetFunctionsBlock();
//Обнулить инфу о блоке функций.
begin
  if Length(Self.Functions) > 0 then begin
    SetLength(Self.Functions,0);
  end;
end;

procedure TPascalCodeModifier.ResetBlocksInfo();
//Обнулить инфу о блоках кода.
begin
  //Константы....
  Self.ResetConstsBlock();
  //Функции...
  Self.ResetFunctionsBlock();
end;

procedure TPascalCodeModifier.ResetConst(var ConstToReset : RPascalConst);
//Обнулить инфу о константе.
begin
  ConstToReset.ConstStart := 0;
  ConstToReset.ConstEnd := 0;
  ConstToReset.Name := '';
  ConstToReset.NameStart := 0;
  ConstToReset.NameEnd := 0;
  ConstToReset.Value := '';
  ConstToReset.ValueStart := 0;
  ConstToReset.ValueEnd := 0;
end;

procedure TPascalCodeModifier.ResetFunction(var FuncToReset : RPascalFunction);
//Обнулить инфу о функции.
begin
  FuncToReset.FunctionStart := 0;
  FuncToReset.FunctionEnd := 0;
  FuncToReset.Name := '';
  FuncToReset.NameStart := 0;
  FuncToReset.NameEnd := 0;
  FuncToReset.IsProcedure := true;
  FuncToReset.IsDeclaration := false;
end;

function TPascalCodeModifier.ParseConsts() : Boolean;
//Пропарсить блок констант...
var
  IControlCodeTools : Boolean;
  MemStream : TMemoryStream;
  CurrTreeNode, ConstSectNode, ConstDefNode : TCodeTreeNode;
  CurrConstNum : Integer;
  
begin
  //Инициализация.
  Result := true;
  //Смотрим - есть ли инфа в CodeTools ?
  if Self.CodeToolsAreUnderControl = false then begin
    //Надо закинуть инфу.
    Self.CodeBuf := CodeToolBoss.CreateFile('tempfile.pas');
    MemStream := TMemoryStream.Create;
    MemStream.Write(Self.FileString[1], Length(Self.FileString));
    Self.CodeBuf.LoadFromStream(MemStream);
    MemStream.Free;
    //И получить експлорера.
    CodeToolBoss.Explore(Self.CodeBuf, Self.ACodeTool, true, false);
    //Отметить на себя контроль CodeTools.
    IControlCodeTools := true;
    Self.CodeToolsAreUnderControl := true;
  end
  else begin
    //Кто-то уже контроллирует объекты.
    IControlCodeTools := false;
  end;
  
  //Собсно поиск констант и забивка инфы.
  //Строим дерево и получаем его корень.
  Self.ACodeTool.BuildTree(false);
  CurrTreeNode := Self.ACodeTool.Tree.Root;
  //Смотрим чего из себя представляет корень. Это должна быть либо прога,
  //либо юнит, либо пакайдж, либо лайбрари.
  if (CurrTreeNode.Desc = ctnProgram) or
     (CurrTreeNode.Desc = ctnPackage) or
     (CurrTreeNode.Desc = ctnLibrary) or
     (CurrTreeNode.Desc = ctnUnit) then
  begin
    //Собсно, это как раз та нода что нужно. Теперь лезем на уровень вниз...
    CurrTreeNode := CurrTreeNode.FirstChild;
    if CurrTreeNode <> nil then begin
      //Ага, это первай чилд. Циклически просматриваем его и братьев (т.е. на том
      //же уровне) - ищем секции с константами.
      repeat
        if CurrTreeNode.Desc = ctnConstSection then begin
          //Ага, секция констант. Дальше в виде чилдов должна быть одна или
          //несколько констант...
          ConstSectNode := CurrTreeNode;  //Чтоб не потерять дерево.
          CurrTreeNode := CurrTreeNode.FirstChild;
          //И пробегаемся по секции.
          repeat
            //Ищем объявления констант.
            if CurrTreeNode.Desc = ctnConstDefinition then begin
              //Ага, это оно. Добавляем элемент в массив.
              CurrConstNum := Length(Self.Consts);
              SetLength(Self.Consts,CurrConstNum+1);
              Self.ResetConst(Self.Consts[CurrConstNum]);
              //Заполняем той инфой что есть сейчас.
              Self.Consts[CurrConstNum].ConstStart := CurrTreeNode.StartPos;
              Self.Consts[CurrConstNum].ConstEnd := CurrTreeNode.EndPos;
              //Получаем имя константы. Выставляем курсор, берем атом, берем инфу.
              Self.ACodeTool.CurPos.StartPos := CurrTreeNode.StartPos;
              Self.ACodeTool.CurPos.EndPos := CurrTreeNode.StartPos;
              Self.ACodeTool.CurPos.Flag := cafNone;
              Self.ACodeTool.ReadNextAtom;
              Self.Consts[CurrConstNum].Name := Self.ACodeTool.GetAtom;
              Self.Consts[CurrConstNum].NameStart := Self.ACodeTool.CurPos.StartPos;
              Self.Consts[CurrConstNum].NameEnd := Self.ACodeTool.CurPos.EndPos;
              //Ищем значение константы...
              ConstDefNode := CurrTreeNode;
              CurrTreeNode := CurrTreeNode.FirstChild;
              repeat
                if CurrTreeNode.Desc = ctnConstant then begin
                  //Ага, вот значение.
                  Self.Consts[CurrConstNum].Value := Copy(Self.FileString, CurrTreeNode.StartPos, CurrTreeNode.EndPos-CurrTreeNode.StartPos );
                  Self.Consts[CurrConstNum].ValueStart := CurrTreeNode.StartPos;
                  Self.Consts[CurrConstNum].ValueEnd := CurrTreeNode.EndPos;
                end;
                //Следующий!
                if Self.Consts[CurrConstNum].Value = '' then begin
                  CurrTreeNode := CurrTreeNode.NextBrother;
                end
                else begin
                  CurrTreeNode := nil;
                end;
              until CurrTreeNode = nil;
              //Закончилось объявление константы.
              CurrTreeNode := ConstDefNode;
            end;
            //Следующий!
            CurrTreeNode := CurrTreeNode.NextBrother;
          until CurrTreeNode = nil;
          //Закончилась секция.
          CurrTreeNode := ConstSectNode;
        end;
        //На следующую ноду.
        CurrTreeNode := CurrTreeNode.NextBrother;
      until CurrTreeNode = nil;
    end
    else begin
      //Гм.. пусто, нету деток... в прочем это не ошибка, останется 0 констант и все.
    end;
  end
  else begin
    //Ошибк.
    Self.ErrorMessage := Self.ClassName+_(' can work only with full Programs, Units, Packages and Libraries.');
    Self.ErrorPosition := CurrTreeNode.StartPos;
    Self.GetErrorLineFromPos();
    Result := false;
  end;
  
  //Чистка мусора если это нужно.
  if IControlCodeTools = true then begin
    Self.CodeBuf := nil;
    Self.ACodeTool := nil;
    IControlCodeTools := false;
    Self.CodeToolsAreUnderControl := false;
  end;
end;

function TPascalCodeModifier.ParseFunctions() : Boolean;
//Пропарсить блок функций...
var
  IControlCodeTools : Boolean;
  MemStream : TMemoryStream;
  CurrTreeNode, HeaderNode  : TCodeTreeNode;
  CurrFuncNum : Integer;
begin
  //Инициализация.
  Result := true;
  //Смотрим - есть ли инфа в CodeTools ?
  if Self.CodeToolsAreUnderControl = false then begin
    //Надо закинуть инфу.
    Self.CodeBuf := CodeToolBoss.CreateFile('tempfile.pas');
    MemStream := TMemoryStream.Create;
    MemStream.Write(Self.FileString[1], Length(Self.FileString));
    Self.CodeBuf.LoadFromStream(MemStream);
    MemStream.Free;
    //И получить експлорера.
    CodeToolBoss.Explore(Self.CodeBuf, Self.ACodeTool, true, false);
    //Отметить на себя контроль CodeTools.
    IControlCodeTools := true;
    Self.CodeToolsAreUnderControl := true;
  end
  else begin
    //Кто-то уже контроллирует объекты.
    IControlCodeTools := false;
  end;
  
  //Строим дерево и получаем его корень.
  Self.ACodeTool.BuildTree(false);
  CurrTreeNode := Self.ACodeTool.Tree.Root;

  //Смотрим чего из себя представляет корень. Это должна быть либо прога,
  //либо юнит, либо пакайдж, либо лайбрари.
  if (CurrTreeNode.Desc = ctnProgram) or
     (CurrTreeNode.Desc = ctnPackage) or
     (CurrTreeNode.Desc = ctnLibrary) or
     (CurrTreeNode.Desc = ctnUnit) then
  begin
    //Собсно, это как раз та нода что нужно. Теперь лезем на уровень вниз...
    CurrTreeNode := CurrTreeNode.FirstChild;
    if CurrTreeNode <> nil then begin
      //Ага, это первай чилд. Циклически просматриваем его и братьев (т.е. на том
      //же уровне) - ищем функции.
      repeat
        if CurrTreeNode.Desc = ctnProcedure then begin
          //Ага, функция. Добавляем элемент в массив.
          CurrFuncNum := Length(Self.Functions);
          SetLength(Self.Functions,Length(Self.Functions)+1);
          Self.ResetFunction(Self.Functions[CurrFuncNum]);
          Self.Functions[CurrFuncNum].FunctionStart := CurrTreeNode.StartPos;
          Self.Functions[CurrFuncNum].FunctionEnd := CurrTreeNode.EndPos;
          //Берем заголовок.
          CurrTreeNode := CurrTreeNode.FirstChild;
          //Смотрим - есть ли брат - если есть - значит нормальная процедура\функция, если нет - forward.
          if CurrTreeNode.NextBrother = nil then begin
            Self.Functions[CurrFuncNum].IsDeclaration := true;
          end
          else begin
            Self.Functions[CurrFuncNum].IsDeclaration := false;
          end;
          //Получаем имя функции.
          Self.ACodeTool.CurPos.StartPos := CurrTreeNode.StartPos;
          Self.ACodeTool.CurPos.EndPos := CurrTreeNode.StartPos;
          Self.ACodeTool.CurPos.Flag := cafNone;
          Self.ACodeTool.ReadNextAtom;
          Self.Functions[CurrFuncNum].Name := Self.ACodeTool.GetAtom;
          Self.Functions[CurrFuncNum].NameStart := Self.ACodeTool.CurPos.StartPos;
          Self.Functions[CurrFuncNum].NameEnd := Self.ACodeTool.CurPos.EndPos;
          //Функция или процедура?
          HeaderNode := CurrTreeNode;
          CurrTreeNode := CurrTreeNode.FirstChild;
          repeat
            if CurrTreeNode <> nil then begin
              if CurrTreeNode.Desc = ctnIdentifier then begin
                Self.Functions[CurrFuncNum].IsProcedure := false;
              end;
              //Следующий!
              if Self.Functions[CurrFuncNum].IsProcedure = true then begin
                CurrTreeNode := CurrTreeNode.NextBrother;
              end
              else begin
                CurrTreeNode := nil;
              end;
            end;
          until CurrTreeNode = nil;
          //Вернуть ноду процедуры.
          CurrTreeNode := HeaderNode.Parent;
        end;
        //Следующий!
        CurrTreeNode := CurrTreeNode.NextBrother;
      until CurrTreeNode = nil;
    end;
  end
  else begin
    //Ошибк.
    Self.ErrorMessage := Self.ClassName+_(' can work only with full Programs, Units, Packages and Libraries.');
    Self.ErrorPosition := CurrTreeNode.StartPos;
    Self.GetErrorLineFromPos();
    Result := false;
  end;
  
  //Чистка мусора если это нужно.
  if IControlCodeTools = true then begin
    Self.CodeBuf := nil;
    Self.ACodeTool := nil;
    IControlCodeTools := false;
    Self.CodeToolsAreUnderControl := false;
  end;
end;

function TPascalCodeModifier.ReParseFile() : Boolean;
var
  IControlCodeTools : Boolean;
  MemStream : TMemoryStream;

begin
  //Инициализация.
  Result := true;
  //Смотрим - есть ли инфа в CodeTools ?
  if Self.CodeToolsAreUnderControl = false then begin
    //Надо закинуть инфу.
    Self.CodeBuf := CodeToolBoss.CreateFile('tempfile.pas');
    MemStream := TMemoryStream.Create;
    MemStream.Write(Self.FileString[1], Length(Self.FileString));
    Self.CodeBuf.LoadFromStream(MemStream);
    MemStream.Free;
    //И получить експлорера.
    CodeToolBoss.Explore(Self.CodeBuf, Self.ACodeTool, true, false);
    //Отметить на себя контроль CodeTools.
    IControlCodeTools := true;
    Self.CodeToolsAreUnderControl := true;
  end
  else begin
    //Кто-то уже контроллирует объекты.
    IControlCodeTools := false;
  end;
  
  //Чистим массивы с инфой....
  Self.ResetBlocksInfo();
  
  //Просто вызываем функции парсинга конкретных блоков.
  Result := Self.ParseConsts();
  if Result = true then Result := Self.ParseFunctions();
  
  //Чистка мусора если это нужно.
  if IControlCodeTools = true then begin
    Self.CodeBuf := nil;
    Self.ACodeTool := nil;
    IControlCodeTools := false;
    Self.CodeToolsAreUnderControl := false;
  end;
end;

function TPascalCodeModifier.GetPosForFirstFunction() : Integer;
//Получить позицию в которую можно вписывать самую первую функцию.
var
  IControlCodeTools : Boolean;
  MemStream : TMemoryStream;
  CurrTreeNode : TCodeTreeNode;
  
begin
  //Инициализация.
  Result := -1;
  
  //Смотрим - есть ли инфа в CodeTools ?
  if Self.CodeToolsAreUnderControl = false then begin
    //Надо закинуть инфу.
    Self.CodeBuf := CodeToolBoss.CreateFile('tempfile.pas');
    MemStream := TMemoryStream.Create;
    MemStream.Write(Self.FileString[1], Length(Self.FileString));
    Self.CodeBuf.LoadFromStream(MemStream);
    MemStream.Free;
    //И получить експлорера.
    CodeToolBoss.Explore(Self.CodeBuf, Self.ACodeTool, true, false);
    //Отметить на себя контроль CodeTools.
    IControlCodeTools := true;
    Self.CodeToolsAreUnderControl := true;
  end
  else begin
    //Кто-то уже контроллирует объекты.
    IControlCodeTools := false;
  end;

  //Строим дерево и получаем его корень.
  Self.ACodeTool.BuildTree(false);
  CurrTreeNode := Self.ACodeTool.Tree.Root;
  
  //Смотрим чего из себя представляет корень.
  //Пока умеет правильно работать только с Program
  if CurrTreeNode.Desc = ctnProgram then begin
    //Если Program - то найти где будет основной begin - функции можно писать выше него.
    CurrTreeNode := CurrTreeNode.FirstChild;
    if CurrTreeNode <> nil then begin
      repeat
        if CurrTreeNode.Desc = ctnBeginBlock then begin
          //Аха, вот оно.
          Result := CurrTreeNode.StartPos;
          CurrTreeNode := nil;
        end;
        if CurrTreeNode <> nil then CurrTreeNode := CurrTreeNode.NextBrother;
      until CurrTreeNode = nil;
    end;
  end
  else begin
    //Иначе - ныфэга нэзнайу %)
    Self.ErrorMessage := _('TPascalCodeModifier.GetPosForFirstFunction can work only with Programs.');
  end;
  
  //Чистка мусора если это нужно.
  if IControlCodeTools = true then begin
    Self.CodeBuf := nil;
    Self.ACodeTool := nil;
    IControlCodeTools := false;
    Self.CodeToolsAreUnderControl := false;
  end;
end;

//---------------------------------------------------//
//      --Чтение и модификация элементов кода--      //
//---------------------------------------------------//

function TPascalCodeModifier.ReadCodeConstValue(const ConstName : AnsiString) : AnsiString;
//Прочитать значение конкретной константы.
var
  I : Integer;
begin
  //Инициализация.
  Result := '';
  
  //Ищем константу...
  for I := 0 to Length(Self.Consts)-1 do begin
    if LowerCase(Self.Consts[I].Name) = LowerCase(ConstName) then begin
      //Нашли.
      Result := Self.Consts[I].Value;
      Break;
    end;
  end;
end;

function TPascalCodeModifier.WriteCodeConstValue(const ConstName, ConstValue : AnsiString) : Boolean;
//Записать значение конкретной константы.
var
  I : Integer;
begin
  //Инициализация.
  Result := false;
  
  //Есть 2 варианта развития событий. Если константа уже есть - её значение просто перезаписывается.
  //Если нет - константа полностью дописывается после последней существующей, в ту же секцию.
  
  //Ищем константу...
  for I := 0 to Length(Self.Consts)-1 do begin
    if LowerCase(Self.Consts[I].Name) = LowerCase(ConstName) then begin
      //Нашли. Пишем новое значение.
      Delete(Self.FileString, Self.Consts[I].ValueStart, Self.Consts[I].ValueEnd-Self.Consts[I].ValueStart);
      Insert(ConstValue, Self.FileString, Self.Consts[I].ValueStart);
      Result := true;
      Break;
    end;
  end;
  
  //Если константа найдена не была - добавляем её целиком после последней.
  if Result = false then begin
    Insert(#13+#10+'  '+ConstName+' = '+ConstValue+';', Self.FileString, Self.Consts[Length(Self.Consts)-1].ConstEnd);
    Result := true;
  end;
  
  //Если константа была добавлена, а значит изменился код - его надо перепропарсить заново.
  if Result = true then begin
    Result := Self.ReParseFile();
  end;
end;

function TPascalCodeModifier.ReadFunctionName(const FullFunctionText : AnsiString) : AnsiString;
//Выпарсить имя функции из полного её кода.
var
  TempModifier : TPascalCodeModifier;
  Parsed : Boolean;
  
begin
  //Инициализация.
  Result := '';
  TempModifier := TPascalCodeModifier.Create;
  Parsed := true;
  
  //Формируем временный "текст проги" с внесением туда текста функции.
  TempModifier.MakNewFile;
  TempModifier.FileString := 'Program Temp;'+#13+#10+FullFunctionText+#13+#10+'begin end.';
  //Парсим.
  try
    TempModifier.ReParseFile();
  except
    //Явно ошибка в FullFunctionText.
    Parsed := false;
    Self.ErrorMessage := _('Error, parsing FullFunctionText argument');
  end;

  //И получаем имя первой функции.
  if Parsed = true then begin
    if Length(TempModifier.Functions) > 0 then begin
      Result := TempModifier.Functions[0].Name;
    end;
  end;
  
  //Чистка мусора.
  TempModifier.Free;
end;

function TPascalCodeModifier.FunctionIsExists(const FunctionName : AnsiString) : Boolean;
//Существует ли функция?
var
  I : Integer;
begin
  //Инициализация.
  Result := false;
  
  //Ищем функцию.
  for I := 0 to Length(Self.Functions)-1 do begin
    if Self.Functions[I].IsDeclaration = false then begin
      //Проверка не forward ли это - т.к. форвард-декларации учитывать не надо.
      if LowerCase(Self.Functions[I].Name) = LowerCase(FunctionName) then begin
        //Нашли.
        Result := true;
        Break;
      end;
    end;
  end;
  
end;

function TPascalCodeModifier.FunctionIsExistsByText(const FullFunctionText : AnsiString) : Boolean;
//Существует ли функция? Поиск идет по имени, которое берется из полного кода функции.
begin
  Result := Self.FunctionIsExists(Self.ReadFunctionName(FullFunctionText));
end;

function TPascalCodeModifier.GetFunctionIndex(const FunctionName : AnsiString) : Integer;
//Получить номер функции с таким именем в массиве с инфой.
var
  I : Integer;
begin
  //Инициализация.
  Result := -1;
  
  //Ищем функцию.
  for I := 0 to Length(Self.Functions)-1 do begin
    if Self.Functions[I].IsDeclaration = false then begin
      //Проверка не forward ли это - т.к. форвард-декларации учитывать не надо.
      if LowerCase(Self.Functions[I].Name) = LowerCase(FunctionName) then begin
        //Нашли.
        Result := I;
        Break;
      end;
    end;
  end;
  
end;

function TPascalCodeModifier.GetFullFunctionText(const FunctionIndex : Integer) : AnsiString;
//Получить полный код функции по её номеру в массиве.
begin
  Result := Copy(Self.FileString, Self.Functions[FunctionIndex].FunctionStart, (Self.Functions[FunctionIndex].FunctionEnd-Self.Functions[FunctionIndex].FunctionStart)+1);
end;

function TPascalCodeModifier.GetFullFunctionText(const FunctionName : AnsiString) : AnsiString;
//Получить полный код функции по её имени.
var
  FuncIndex : Integer;
begin
  //Инициализация.
  Result := '';
  
  //Если есть такая функция - то получить её индекс.
  FuncIndex := Self.GetFunctionIndex(FunctionName);
  //И собсно саму функцию.
  if FuncIndex >= 0 then begin
    Result := GetFullFunctionText(FuncIndex);
  end;
end;

function TPascalCodeModifier.WriteFunction(const FunctionIndex : Integer; const FullFunctionText : AnsiString) : Boolean;
//Записать функцию в код, если она уже есть - заменить.
begin
  //Инициализация.
  Result := false;
  
  //Удаляем старый текст функции.
  Delete(Self.FileString, Self.Functions[FunctionIndex].FunctionStart, (Self.Functions[FunctionIndex].FunctionEnd-Self.Functions[FunctionIndex].FunctionStart)+1);
  //И собсно дописываем функцию.
  Insert(FullFunctionText, Self.FileString, Self.Functions[FunctionIndex].FunctionStart);
  //Код надо перепропарсить заново.
  Result := Self.ReParseFile();
end;

function TPascalCodeModifier.WriteFunction(const FunctionName, FullFunctionText : AnsiString) : Boolean;
//Записать функцию в код, если она уже есть - заменить.
var
  FuncIndex, InputPos : Integer;
  TailToAdd : AnsiString;
begin
  //Инициализация.
  Result := false;

  //Есть ли функция?
  FuncIndex := Self.GetFunctionIndex(FunctionName);
  if FuncIndex >= 0 then begin
    //Есть такое дело. Вызываем функцию добавляющую по индексу.
    Result := Self.WriteFunction(FuncIndex, FullFunctionText);
  end
  else begin
    //Нету - бум дописывать после последней.
    if Length(Self.Functions) > 0 then begin
      //В коде есть как минимум 1 функция
      InputPos := (Self.Functions[Length(Self.Functions)-1].FunctionEnd)+1;
      TailToAdd := '';
      //И добавиь дополнительный разделитель %).
      Insert(#13+#10, Self.FileString, InputPos);
      InputPos := InputPos+2;
    end
    else begin
      //В коде нету ни одной функции.
      InputPos := Self.GetPosForFirstFunction();
      TailToAdd := #13+#10+#13+#10;
    end;
    
    //Собсно вставляем функцию.
    if InputPos > 0 then begin
      Insert(#13+#10+FullFunctionText+TailToAdd, Self.FileString, InputPos);
      //Код надо перепропарсить заново.
      Result := Self.ReParseFile();
    end;
  end;
end;

end.